.. _examples:

Selected Examples
-----------------

.. _polsel:

Standard Model with internal polarization selection
===================================================

|recola| 1.5.0+ supports the selection of internal polarizations which is
based on :cite:`Ballestrero:2017bxn`, :cite:`Ballestrero:2019qoy` and has been
used with Recola in :cite:`Denner:2020bcz`, :cite:`Denner:2020eck` and
:cite:`Denner:2021csi`.
Examples of how to use this feature are given below:

.. tabs::

  .. group-tab:: WW-Fortran90

    .. code-block:: fortran

        program internal_projection
          use recola
          implicit none

          integer, parameter :: dp = 8
          real (kind=dp) :: p_full (0:3,1:6),p_full_prod(0:3,1:4), p_full_dec1(0:3,1:3), p_full_dec2(0:3,1:3)
          real (kind=dp) :: A2(0:1), B2(0:1), C2(0:1), D2(0:1), E2(0:1)
          real (kind=dp) :: M2prod, M2dec1, M2dec2, M2full
          real (kind=dp) ::alphas, MW, MZ, wwidth, alpha

          p_full(:,1)=[5000.0000000000000d0, 0.0000000000000000d0, 0.0000000000000000d0, 5000.0000000000000d0]
          p_full(:,2)=[5000.0000000000000d0, 0.0000000000000000d0, 0.0000000000000000d0,-5000.0000000000000d0]
          p_full(:,3)=[3243.8985189361665d0, 695.23069130847887d0,-3166.9342850974826d0,-100.29516884221320d0]
          p_full(:,4)=[1756.1014810638335d0, 433.87511031166298d0,-1700.8566566424388d0,-52.263122770570874d0]
          p_full(:,5)=[2249.2998992648813d0,-494.85571955991441d0, 2193.9693904301166d0, 31.083235152524409d0]
          p_full(:,6)=[2750.7001007351187d0,-634.25008206022721d0, 2673.8215513098039d0, 121.47505646025964d0]

          p_full_prod(:,1) = p_full(:,1)
          p_full_prod(:,2) = p_full(:,2)
          p_full_prod(:,3) = p_full(:,3) +p_full(:,4)
          p_full_prod(:,4) = p_full(:,5) +p_full(:,6)

          p_full_dec1(:,1) = p_full_prod(:,3)
          p_full_dec1(:,2) = p_full(:,3)
          p_full_dec1(:,3) = p_full(:,4)

          p_full_dec2(:,1) = p_full_prod(:,4)
          p_full_dec2(:,2) = p_full(:,5)
          p_full_dec2(:,3) = p_full(:,6)

          ! input parameter
          alphas = 0.117d0
          MW = 80.3579736098775d0
          MZ = 91.1534806191828d0
          wwidth = 2.08429899827822d0
          alpha = 7.555310522369d-3

          ! compute the full M^2
          call use_gfermi_scheme_rcl(a=alpha)
          call set_pole_mass_W_rcl(MW,wwidth)
          call set_pole_mass_Z_rcl(MZ,0d0)
          call set_complex_mass_scheme_rcl()

          call set_print_level_squared_amplitude_rcl(3)
          call set_resonant_particle_rcl("W-")
          call define_process_rcl(1,"A A -> W-[-](nu_e~ e-) W+[-](mu+ nu_mu)","NLO")

          call generate_processes_rcl
          call compute_process_rcl(1, p_full, "NLO", A2)
          call get_squared_amplitude_rcl(1,0,"LO",M2full)
          write(*,*) "ME2 = ", M2full
          call reset_recola_rcl()

          call use_gfermi_scheme_rcl(a=alpha)
          call set_pole_mass_W_rcl(MW,0d0)
          call set_pole_mass_Z_rcl(MZ,0d0)
          call set_on_shell_scheme_rcl()
          ! compute the production/decay M^2
          call define_process_rcl(1,"A A -> W-[-] W+[-]","NLO")
          call define_process_rcl(2," W-[-] -> nu_e~ e-","NLO")
          call define_process_rcl(3," W+[-] -> mu+ nu_mu","NLO")

          call generate_processes_rcl()
          call compute_process_rcl(1, p_full_prod, "NLO", B2)
          call compute_process_rcl(2, p_full_dec1, "NLO", C2)
          call compute_process_rcl(3, p_full_dec2, "NLO", D2)

          call get_squared_amplitude_rcl(1,0,"LO",M2prod)
          call get_squared_amplitude_rcl(2,0,"LO",M2dec1)
          call get_squared_amplitude_rcl(3,0,"LO",M2dec2)

          write(*,*) "ME2 = ", M2prod*M2dec1*M2dec2/(MW*wwidth)**4

          call reset_recola_rcl
        end program internal_projection

.. bibliography:: ../references.bib
   :filter: docname in docnames